Meta: Add files to repository

System/Api/Dns.HC

@@ -0,0 +1,28 @@
+#define DNS_REQUEST_PTR 0x300010
+
+MemSet(DNS_REQUEST_PTR, NULL, sizeof(U64));
+
+class DnsRequest {
+    U64 host;
+    U64 pointer_to_u32;
+};
+
+U32 @dns_query(U8* host)
+{
+    U32 res = 0;
+    if (!host)
+        return U32_MAX;
+    if (!StrICmp("catbox.moe", host)) {
+        return 0x0a1400fe;
+    }
+    DnsRequest* request = CAlloc(sizeof(DnsRequest), Fs->code_heap);
+    request->host = StrNew(host, erythros_mem_task);
+    request->pointer_to_u32 = &res;
+    U64* request_ptr = DNS_REQUEST_PTR;
+    while (*request_ptr)
+        Sleep(1);
+    LXchgU32(request_ptr, request);
+    while (!res)
+        Sleep(1);
+    return res;
+}

System/Api/Icmp.HC

@@ -0,0 +1,32 @@
+#define ICMP_REQUEST_PTR 0x300020
+
+MemSet(ICMP_REQUEST_PTR, NULL, sizeof(U64));
+
+class IcmpRequest {
+    U64 addr;
+    U64 iden;
+    U64 seq;
+    U64 pointer_to_u32;
+};
+
+U32 @icmp_echo_request(U32 addr, U16 iden, U16 seq, IcmpRequest* request, I64 count)
+{
+    U32 res = 0; // low 16 = ttl, hi 16 = payload size
+    request->addr = addr;
+    request->iden = iden;
+    request->seq = seq;
+    request->pointer_to_u32 = &res;
+    I64 start_jiffies = cnts.jiffies;
+    U64* request_ptr = ICMP_REQUEST_PTR;
+    if (!count)
+        *request_ptr = NULL;
+    while (*request_ptr) {
+        if (!(cnts.jiffies < start_jiffies + 1000))
+            return res;
+        Sleep(1);
+    }
+    LXchgU32(request_ptr, request);
+    while (!res && cnts.jiffies < start_jiffies + 1000)
+        Sleep(1);
+    return res;
+}

System/Api/Ipv4.HC

@@ -0,0 +1,9 @@
+U32 @ipv4_address(I64 o3, I64 o2, I64 o1, I64 o0)
+{
+    U32 addr = NULL;
+    addr.u8[3] = o3;
+    addr.u8[2] = o2;
+    addr.u8[1] = o1;
+    addr.u8[0] = o0;
+    return addr;
+}

System/Api/MD5.HC

@@ -0,0 +1,144 @@
+/*
+ * Simple MD5 implementation
+ *
+ * https://gist.github.com/creationix/4710780
+ */
+
+U32 md5_r[64] = { 7, 12, 17, 22, 7, 12, 17, 22, 7, 12, 17, 22, 7, 12, 17, 22,
+    5, 9, 14, 20, 5, 9, 14, 20, 5, 9, 14, 20, 5, 9, 14, 20,
+    4, 11, 16, 23, 4, 11, 16, 23, 4, 11, 16, 23, 4, 11, 16, 23,
+    6, 10, 15, 21, 6, 10, 15, 21, 6, 10, 15, 21, 6, 10, 15, 21 };
+// Use binary integer part of the sines of integers (in radians) as constants//
+// Initialize variables:
+U32 md5_k[64] = {
+    0xd76aa478, 0xe8c7b756, 0x242070db, 0xc1bdceee, 0xf57c0faf, 0x4787c62a,
+    0xa8304613, 0xfd469501, 0x698098d8, 0x8b44f7af, 0xffff5bb1, 0x895cd7be,
+    0x6b901122, 0xfd987193, 0xa679438e, 0x49b40821, 0xf61e2562, 0xc040b340,
+    0x265e5a51, 0xe9b6c7aa, 0xd62f105d, 0x02441453, 0xd8a1e681, 0xe7d3fbc8,
+    0x21e1cde6, 0xc33707d6, 0xf4d50d87, 0x455a14ed, 0xa9e3e905, 0xfcefa3f8,
+    0x676f02d9, 0x8d2a4c8a, 0xfffa3942, 0x8771f681, 0x6d9d6122, 0xfde5380c,
+    0xa4beea44, 0x4bdecfa9, 0xf6bb4b60, 0xbebfbc70, 0x289b7ec6, 0xeaa127fa,
+    0xd4ef3085, 0x04881d05, 0xd9d4d039, 0xe6db99e5, 0x1fa27cf8, 0xc4ac5665,
+    0xf4292244, 0x432aff97, 0xab9423a7, 0xfc93a039, 0x655b59c3, 0x8f0ccc92,
+    0xffeff47d, 0x85845dd1, 0x6fa87e4f, 0xfe2ce6e0, 0xa3014314, 0x4e0811a1,
+    0xf7537e82, 0xbd3af235, 0x2ad7d2bb, 0xeb86d391
+};
+
+// leftrotate function
+U32 LEFTROTATE(U32 x, U32 c) { return (((x) << (c)) | ((x) >> (32 - (c)))); }
+
+U0 md5(U8* initial_msg, U32 initial_len, U32* md5_h)
+{
+
+    // These vars will contain the hash
+    U32 md5_h0, md5_h1, md5_h2, md5_h3;
+
+    // Message (to prepare)
+    U8* msg = NULL;
+
+    // Note: All variables are unsigned 32 bit and wrap modulo 2^32 when
+    // calculating
+
+    // r specifies the per-round shift amounts
+
+    md5_h0 = 0x67452301;
+    md5_h1 = 0xefcdab89;
+    md5_h2 = 0x98badcfe;
+    md5_h3 = 0x10325476;
+
+    // Pre-processing: adding a single 1 bit
+    // append "1" bit to message
+    /* Notice: the input bytes are considered as bits strings,
+       where the first bit is the most significant bit of the byte.[37] */
+
+    // Pre-processing: padding with zeros
+    // append "0" bit until message length in bit ≡ 448 (mod 512)
+    // append length mod (2 pow 64) to message
+
+    U32 new_len;
+    for (new_len = initial_len * 8 + 1; new_len % 512 != 448; new_len++)
+        ;
+    new_len /= 8;
+
+    msg = CAlloc(new_len + 64, erythros_mem_task); // also appends "0" bits
+                                                   // (we alloc also 64 extra bytes...)
+    MemCpy(msg, initial_msg, initial_len);
+    msg[initial_len] = 128; // write the "1" bit
+
+    U32 bits_len = 8 * initial_len;      // note, we append the len
+    MemCpy(msg + new_len, &bits_len, 4); // in bits at the end of the buffer
+
+    // Process the message in successive 512-bit chunks:
+    // for each 512-bit chunk of message:
+    U32 offset;
+    for (offset = 0; offset < new_len; offset += (512 / 8)) {
+
+        // break chunk into sixteen 32-bit words w[j], 0 ≤ j ≤ 15
+        U32* w = (msg + offset)(U32*);
+
+        // Initialize hash value for this chunk:
+        U32 a = md5_h0;
+        U32 b = md5_h1;
+        U32 c = md5_h2;
+        U32 d = md5_h3;
+
+        // Main loop:
+        U32 i;
+        for (i = 0; i < 64; i++) {
+
+            U32 f, g;
+
+            if (i < 16) {
+                f = (b & c) | ((~b) & d);
+                g = i;
+            } else if (i < 32) {
+                f = (d & b) | ((~d) & c);
+                g = (5 * i + 1) % 16;
+            } else if (i < 48) {
+                f = b ^ c ^ d;
+                g = (3 * i + 5) % 16;
+            } else {
+                f = c ^ (b | (~d));
+                g = (7 * i) % 16;
+            }
+
+            U32 temp = d;
+            d = c;
+            c = b;
+            // printf("rotateLeft(%x + %x + %x + %x, %d)\n", a, f, k[i], w[g], r[i]);
+            b = b + LEFTROTATE((a + f + md5_k[i] + w[g]), md5_r[i]);
+            a = temp;
+        }
+
+        // Add this chunk's hash to result so far:
+
+        md5_h0 += a;
+        md5_h1 += b;
+        md5_h2 += c;
+        md5_h3 += d;
+    }
+
+    md5_h[0] = md5_h0;
+    md5_h[1] = md5_h1;
+    md5_h[2] = md5_h2;
+    md5_h[3] = md5_h3;
+
+    // cleanup
+    Free(msg);
+}
+
+U8* md5_string(U8* buf, I64 size)
+{
+    U32 md5_h[4];
+    md5(buf, size, &md5_h[0]);
+    U8* str = CAlloc(33, erythros_mem_task);
+    StrPrint(str + StrLen(str), "%02x%02x%02x%02x", md5_h[0].u8[0],
+        md5_h[0].u8[1], md5_h[0].u8[2], md5_h[0].u8[3]);
+    StrPrint(str + StrLen(str), "%02x%02x%02x%02x", md5_h[1].u8[0],
+        md5_h[1].u8[1], md5_h[1].u8[2], md5_h[1].u8[3]);
+    StrPrint(str + StrLen(str), "%02x%02x%02x%02x", md5_h[2].u8[0],
+        md5_h[2].u8[1], md5_h[2].u8[2], md5_h[2].u8[3]);
+    StrPrint(str + StrLen(str), "%02x%02x%02x%02x", md5_h[3].u8[0],
+        md5_h[3].u8[1], md5_h[3].u8[2], md5_h[3].u8[3]);
+    return str;
+}

System/Api/NetInfo.HC

@@ -0,0 +1,32 @@
+#define NETINFO_REQUEST_PTR 0x300030
+
+MemSet(NETINFO_REQUEST_PTR, NULL, sizeof(U64));
+
+class NetInfoRequest {
+    U64 mac_address;
+    U64 ipv4_address;
+    U64 ipv4_netmask;
+    U64 ipv4_network;
+    U64 ipv4_gateway;
+    U64 dns_server_address;
+    U64 dns_server_port;
+    U64 rx_bytes;
+    U64 rx_frames;
+    U64 tx_bytes;
+    U64 tx_frames;
+    U64 pointer_to_u32;
+};
+
+NetInfoRequest* @net_info_request()
+{
+    U32 res = 0;
+    NetInfoRequest* req = CAlloc(sizeof(NetInfoRequest), Fs->code_heap);
+    req->pointer_to_u32 = &res;
+    U64* request_ptr = NETINFO_REQUEST_PTR;
+    while (*request_ptr)
+        Sleep(1);
+    LXchgU32(request_ptr, req);
+    while (!res)
+        Sleep(1);
+    return req;
+}

System/Api/Tcp.HC

@@ -0,0 +1,210 @@
+#define TCP_SOCKET_REQUEST_PTR 0x300000
+#define TCP_BIND_REQUEST_PTR 0x300040
+#define TCP_ACCEPT_REQUEST_PTR 0x300050
+
+MemSet(TCP_SOCKET_REQUEST_PTR, NULL, sizeof(U64));
+
+// TcpSocket states
+
+#define TCP_SOCKET_STATE_IDLE 0
+#define TCP_SOCKET_STATE_ESTABLISHED 1
+#define TCP_SOCKET_STATE_CLOSED 2
+#define TCP_SOCKET_STATE_CONNECTING 4
+
+class TcpSocket {
+    U64 remote_addr;
+    U64 remote_port;
+    U64 state;
+    U64 receive_buffer_ptr; // Pointer to receive buffer in physical memory
+    U64 receive_buffer_size;
+    U64 receive_buffer_filled; // Number of bytes Net has put into buffer
+    U64 receive_buffer_kick;   // Net sets this to 1 when it has data available for
+                               // us, we set back to 0 when ready to receive
+    U64 send_buffer_ptr;
+    U64 send_buffer_size;
+    U64 send_buffer_filled;
+    U64 send_buffer_kick; // We set this to 1 when we have data available to net,
+                          // Net sets back to 0 when ready to receive
+    U0(*close)
+    ();
+    U64(*receive)
+    (U64 buf, U64 length);
+    U0(*send)
+    (U64 buf, U64 length);
+};
+
+class TcpBind {
+    U64 port;
+    U64 function;
+    U64 response_code;
+};
+
+U8 @tcp_close_wrapper_function[16]
+    = { 0x55, 0x48, 0x8B, 0xEC, 0x68, 0x78,
+          0x56, 0x34, 0x12, 0xE8, 0x02, 0x6D,
+          0x02, 0x00, 0x5D, 0xC3 };
+
+U8 @tcp_receive_wrapper_function[32] = {
+    0x55, 0x48, 0x8B, 0xEC, 0x56, 0x57, 0x48, 0x8B, 0x75, 0x18, 0x48,
+    0x8B, 0x7D, 0x10, 0x56, 0x57, 0x68, 0x78, 0x56, 0x34, 0x12, 0xE8,
+    0x5E, 0x62, 0x02, 0x00, 0x5F, 0x5E, 0x5D, 0xC2, 0x10, 0x00
+};
+
+U8 @tcp_send_wrapper_function[32] = {
+    0x55, 0x48, 0x8B, 0xEC, 0x56, 0x57, 0x48, 0x8B, 0x75, 0x18, 0x48,
+    0x8B, 0x7D, 0x10, 0x56, 0x57, 0x68, 0x78, 0x56, 0x34, 0x12, 0xE8,
+    0x5E, 0x62, 0x02, 0x00, 0x5F, 0x5E, 0x5D, 0xC2, 0x10, 0x00
+};
+
+U0 @tcp_socket_send(TcpSocket* s, U64 buf, U64 length)
+{
+    while (s->send_buffer_kick)
+        Sleep(1);
+    U64 pos = 0;
+    U64 bytes_to_send = 0;
+    while (pos < length) {
+        if ((length - pos) > s->send_buffer_size)
+            bytes_to_send = s->send_buffer_size;
+        else
+            bytes_to_send = length - pos;
+        MemCpy(s->send_buffer_ptr, buf + pos, bytes_to_send);
+        s->send_buffer_filled = bytes_to_send;
+        s->send_buffer_kick = 1;
+        pos += bytes_to_send;
+        while (s->send_buffer_kick)
+            Sleep(1);
+    }
+}
+
+U64 @tcp_socket_receive(TcpSocket* s, U64 buf, U64 size)
+{
+    s->receive_buffer_size = size;
+    s->receive_buffer_kick = 0;
+    while (!s->receive_buffer_kick) {
+        if (s->state == TCP_SOCKET_STATE_CLOSED)
+            return NULL;
+        Sleep(1);
+    }
+    U64 bytes_received = s->receive_buffer_filled;
+    if (bytes_received > 0) {
+        MemCpy(buf, s->receive_buffer_ptr, bytes_received);
+    }
+    return bytes_received;
+}
+
+U0 @tcp_wait_for_connection_established(TcpSocket* s)
+{
+    while (s->state != TCP_SOCKET_STATE_ESTABLISHED)
+        Sleep(1);
+}
+
+U0 @tcp_socket_close(TcpSocket* s)
+{
+    if (s->close)
+        Free(s->close);
+    if (s->receive)
+        Free(s->receive);
+    if (s->send)
+        Free(s->send);
+    s->state = TCP_SOCKET_STATE_CLOSED;
+}
+
+TcpSocket* @tcp_socket_create(U8* host, U64 port)
+{
+    U64 addr = @dns_query(host);
+    TcpSocket* s = CAlloc(sizeof(TcpSocket), erythros_mem_task->code_heap);
+    s->remote_addr = addr;
+    s->remote_port = port;
+
+    U64 a;
+
+    s->close = MAlloc(16, erythros_mem_task->code_heap);
+    MemCpy(s->close, @tcp_close_wrapper_function, 16);
+    a = s->close;
+    a += 0x05;
+    MemSetU32(a, s, 1);
+    a = s->close;
+    a += 0x09;
+    @patch_call_rel32(a, &@tcp_socket_close);
+
+    s->receive = MAlloc(25, erythros_mem_task->code_heap);
+    MemCpy(s->receive, @tcp_receive_wrapper_function, 32);
+    a = s->receive;
+    a += 0x11;
+    MemSetU32(a, s, 1);
+    a = s->receive;
+    a += 0x15;
+    @patch_call_rel32(a, &@tcp_socket_receive);
+
+    s->send = MAlloc(32, erythros_mem_task->code_heap);
+    MemCpy(s->send, @tcp_send_wrapper_function, 32);
+    a = s->send;
+    a += 0x11;
+    MemSetU32(a, s, 1);
+    a = s->send;
+    a += 0x15;
+    @patch_call_rel32(a, &@tcp_socket_send);
+
+    U64* request_ptr = TCP_SOCKET_REQUEST_PTR;
+    while (*request_ptr)
+        Sleep(1);
+    LXchgU32(request_ptr, s);
+    return s;
+}
+
+U64 @tcp_socket_bind(U64 port, U64 function)
+{
+    if (!port || !function)
+        return NULL;
+
+    TcpBind* b = CAlloc(sizeof(TcpBind), erythros_mem_task->code_heap);
+    b->port = port;
+    b->function = function; // U0 my_spawn_wrapper_function(TcpSocket* s)
+
+    U64* request_ptr = TCP_BIND_REQUEST_PTR;
+    while (*request_ptr)
+        Sleep(1);
+    LXchgU32(request_ptr, b);
+    while (*request_ptr)
+        Sleep(1);
+    U64 res = b->response_code;
+    Free(b);
+    return res;
+}
+
+TcpSocket* @tcp_socket_accept(TcpSocket* s)
+{
+    if (!s || !s->remote_addr || !s->remote_port)
+        return NULL;
+
+    U64 a;
+
+    s->close = MAlloc(16, erythros_mem_task->code_heap);
+    MemCpy(s->close, @tcp_close_wrapper_function, 16);
+    a = s->close;
+    a += 0x05;
+    MemSetU32(a, s, 1);
+    a = s->close;
+    a += 0x09;
+    @patch_call_rel32(a, &@tcp_socket_close);
+
+    s->receive = MAlloc(25, erythros_mem_task->code_heap);
+    MemCpy(s->receive, @tcp_receive_wrapper_function, 32);
+    a = s->receive;
+    a += 0x11;
+    MemSetU32(a, s, 1);
+    a = s->receive;
+    a += 0x15;
+    @patch_call_rel32(a, &@tcp_socket_receive);
+
+    s->send = MAlloc(32, erythros_mem_task->code_heap);
+    MemCpy(s->send, @tcp_send_wrapper_function, 32);
+    a = s->send;
+    a += 0x11;
+    MemSetU32(a, s, 1);
+    a = s->send;
+    a += 0x15;
+    @patch_call_rel32(a, &@tcp_socket_send);
+
+    return s;
+}

System/Api/Tls.HC

@@ -0,0 +1,99 @@
+#define TLS_CONNECT_TASK_STACK_SIZE 524288
+#define TLS_CLIENT_MESSAGE_BUFFER_SIZE 0xFFFF
+
+class TlsSocket : TcpSocket {
+    U64 ctx;
+    U8 client_message[TLS_CLIENT_MESSAGE_BUFFER_SIZE];
+};
+
+U0 @tls_send_pending(TlsSocket* s)
+{
+    U32 out_buffer_len = 0;
+    U8* out_buffer = @tls_get_write_buffer(s->ctx, &out_buffer_len);
+    if (out_buffer && out_buffer_len) {
+        @tcp_socket_send(s, out_buffer, out_buffer_len);
+        @tls_buffer_clear(s->ctx);
+    }
+}
+
+U0 @tls_socket_send(TlsSocket* s, U64 buf, U64 size)
+{
+    @tls_write(s->ctx, buf, size);
+    @tls_send_pending(s);
+}
+
+U64 @tls_socket_receive(TlsSocket* s, U8* buf, I64 size)
+{
+    I64 len = @tcp_socket_receive(s, s->client_message, TLS_CLIENT_MESSAGE_BUFFER_SIZE);
+    if (len) {
+        @tls_consume_stream(s->ctx, s->client_message, len, NULL);
+        @tls_send_pending(s);
+    }
+    return @tls_read(s->ctx, buf, size);
+}
+
+U0 @tls12_connect(TlsSocket* s)
+{
+    I64 len;
+    @tls_client_connect(s->ctx);
+    @tls_send_pending(s);
+    while (!@tls_established(s->ctx)) {
+        len = @tcp_socket_receive(s, &s->client_message, TLS_CLIENT_MESSAGE_BUFFER_SIZE);
+        if (len) {
+            @tls_consume_stream(s->ctx, &s->client_message, len, NULL);
+            @tls_send_pending(s);
+        }
+        Sleep(1);
+    }
+}
+
+TlsSocket* @tls_socket_create(U8* server_name, U64 port = 443)
+{
+    U64 addr = @dns_query(server_name);
+    TlsSocket* s = CAlloc(sizeof(TlsSocket), erythros_mem_task->code_heap);
+    s->remote_addr = addr;
+    s->remote_port = port;
+
+    U64 a;
+
+    s->close = MAlloc(16, erythros_mem_task->code_heap);
+    MemCpy(s->close, @tcp_close_wrapper_function, 16);
+    a = s->close;
+    a += 0x05;
+    MemSetU32(a, s, 1);
+    a = s->close;
+    a += 0x09;
+    @patch_call_rel32(a, &@tcp_socket_close);
+
+    s->receive = MAlloc(25, erythros_mem_task->code_heap);
+    MemCpy(s->receive, @tcp_receive_wrapper_function, 32);
+    a = s->receive;
+    a += 0x11;
+    MemSetU32(a, s, 1);
+    a = s->receive;
+    a += 0x15;
+    @patch_call_rel32(a, &@tls_socket_receive);
+
+    s->send = MAlloc(32, erythros_mem_task->code_heap);
+    MemCpy(s->send, @tcp_send_wrapper_function, 32);
+    a = s->send;
+    a += 0x11;
+    MemSetU32(a, s, 1);
+    a = s->send;
+    a += 0x15;
+    @patch_call_rel32(a, &@tls_socket_send);
+
+    U64* request_ptr = TCP_SOCKET_REQUEST_PTR;
+    while (*request_ptr)
+        Sleep(1);
+    LXchgU32(request_ptr, s);
+
+    while (s->state != TCP_SOCKET_STATE_ESTABLISHED)
+        Sleep(1);
+
+    s->ctx = @tls_create_context(0, TLS_V12);
+    @tls_sni_set(s->ctx, StrNew(server_name, erythros_mem_task->code_heap));
+    Spawn(&@tls12_connect, s, , , , TLS_CONNECT_TASK_STACK_SIZE);
+
+    return s;
+}